Example: Morph peptide and receptor

The following script was used:

# Y2R_active_inactive_YY_morph.pml
# ---------------------------------

reinitialize

# load structures
# ---------------
fetch 7yon, active
fetch 7ddz, inactive
#load YYi_model_for_morph.pdb, YYi
align model inactive and name CA, model active and name CA

# create objects
# --------------
create Y2a, active and chain R
create YYa, active and chain L
create Y2i, inactive and chain A and resi 1-343 ;# omit ICL3 fusion
copy YYi, YYa ; #we copy the peptide to a new object. After setting the view, we will shift this peptide (see below)

#create Galpha, chain A
#create Gbeta, chain B
#create Ggamma, chain G

# general definitions and graphics
# --------------------------------
set hash_max, 100
set bg_rgb, white
set depth_cue, on
set fog, 1.0
set fog_start, 0.6
set orthoscopic, on
clip slab, 100
set opaque_background, on
set ray_shadows, off
hide everything
#@D:\pymol_examples\def_colours.pml

# fold cartoon
# ------------
cmd.dss(quiet=1)
set cartoon_fancy_helices, on
# set cartoon_highlight_color, white
#set cartoon_transparency, 0.7, resi 233-249 ;# this is to provide a better view for the helix 6 movement in ray tracing mode
show cartoon, Y*
#color orange, YY
set cartoon_color, gold, Y2*
set cartoon_color, orange, YY*
#color deepblue, Gbeta
#color aquamarine, Ggamma
#set cartoon_color, paleblue, receptor
#util.chainbow()

# viewpoint
# ---------
#orient Y2a ; # this orients the 7TM domain along its principal axis such that the helices are parallel to x (longest dimension)
#turn z, 90 ; # rotate 7TM such that helices are vertical
#turn y, -90 ; # rotate around vertical axis
#zoom
# ***********PASTE VIEW MATRIX HERE ************
#viewport 400,600

set_view (\
     0.802717209,    0.122951634,    0.583526075,\
    -0.466776222,   -0.479430526,    0.743127942,\
     0.371141285,   -0.868901372,   -0.327459961,\
    -0.001885910,    0.006367192, -266.221008301,\
   170.471084595, 169.305999756, 136.994247437,\
   239.174133301, 291.866607666,   20.000000000 )

# morph
# -----
util.performance(0)
#delete active or inactive
set cartoon_color, gold, not chain L
set cartoon_color, orange, chain L
translate [0,10,0], YYi ;# shift the YY peptide in the inactive conformation 10 Ang. upwards
morph morph_Y2, Y2i, Y2a
morph morph_YY, YYi, YYa
enable morph* ; #switch both objects visible
mset 1 x30
madd 1-30
madd 30 x30
madd 30-1
set cartoon_color, gold, not chain L
set cartoon_color, orange, chain L
# we have to specigy the view matrix twice. Above, to be able to shift the peptide along y axis. Here, because the view zoom is changed by the morphing procedure.
set_view (\
     0.802717209,    0.122951634,    0.583526075,\
    -0.466776222,   -0.479430526,    0.743127942,\
     0.371141285,   -0.868901372,   -0.327459961,\
    -0.001885910,    0.006367192, -266.221008301,\
   170.471084595, 169.305999756, 136.994247437,\
   239.174133301, 291.866607666,   20.000000000 )
mplay
viewport 350,600

# for final raytracing:
# util.performance(0)
# ray/draw 500, 900

# png 4eiy_protein.png