Tutorial: Animate the conformational switch for the extracellular and cytosolic halves of the receptor separately after another and show ligand and G-protein binding .

The following script was used:

# Y2R_superpose_active_inactive_morph_intermediate_YY.pml
# -------------------------------------------------------

reinitialize

# load structures
# ---------------
fetch 7yon, active
fetch 7ddz, inactive
align model inactive and name CA, model active and name CA

# create objects
# --------------
create Y2a, active and chain R
create YYa, active and chain L
create Y2i, inactive and chain A and resi 1-343 ;# omit ICL3 fusion
copy YYi, YYa ; #we copy the peptide to a new object. After setting the view, we will shift this peptide (see below)

alter (Y2i), segi='E' ; #update will only work if all atoms have identical segi,chain,resn,resi,name,alt!
alter (Y2i), chain='R'
copy Y2inter, Y2i ; #generate an intermediate
# copy the top half (extracellular side) of the molecule from the active conformation to intermediate
update Y2inter and resi 48-62+99-135+175-230+280-316, Y2a and resi 48-62+99-135+175-230+280-316

create G_a, chain A+B+G and active
copy G_i, G_a

# general definitions and graphics
# --------------------------------
set hash_max, 100
set bg_rgb, white
set depth_cue, on
set fog, 1.0
set fog_start, 0.6
set orthoscopic, on
clip slab, 100
set opaque_background, on
set ray_shadows, off
hide everything

# fold cartoon
# ------------
cmd.dss(quiet=1)
set cartoon_fancy_helices, on
# set cartoon_highlight_color, white
#set cartoon_transparency, 0.7, resi 233-249 ;# this is to provide a better view for the helix 6 movement in ray tracing mode
show cartoon, Y* or G*


# viewpoint
# ---------
# ***********PASTE VIEW MATRIX HERE ************
#viewport 400,600
# need to set matrix twice. Here for the translate command to work
set_view (\
     0.802717209,    0.122951634,    0.583526075,\
    -0.466776222,   -0.479430526,    0.743127942,\
     0.371141285,   -0.868901372,   -0.327459961,\
    -0.002007872,    0.007674277, -472.066711426,\
   174.404602051,  180.046813965,  170.140151978,\
   444.443115234,  497.135711670,   20.000000000 )

# morph
# -----
util.performance(0)
# morph Y2
morph morph01, Y2i, Y2inter
morph morph02, Y2inter, Y2a
create morph01, morph02, 0, 31 ; # append all states (0) from morph02 to morph01 (starting at 31)
delete morph02
set cartoon_color, gold

# morph YY
translate [0,10,0], YYi ;# shift the YY peptide in the inactive conformation 10 Ang. upwards
morph morph_YY, YYi, YYa
# the following loop generates 30 states of the YYa conformation to add to morph_YY in the next step
python
for i in range(1,31):
     cmd.create('morph_Yadd','YYa',0,-1)
python end
create morph_YY, morph_Yadd, 0, 31
delete morph_Yadd
set cartoon_color, tv_orange, morph_YY

# morph G_proteins
translate [0,-10,0], G_i ;# shift the G proteins in the inactive conformation 10 Ang. down
copy morph_G, G_i
# the following loop generates 30 states of the G_i conformation to place before the morph_G morph
python
for i in range(1,30):
     cmd.create('morph_G','G_i',0,-1)
python end
morph morph_Gadd, G_i, G_a
create morph_G, morph_Gadd, 0, 31
delete morph_Gadd
set cartoon_color, tv_orange, morph_YY
set cartoon_color, firebrick, chain A
set cartoon_color, deepblue, chain B
set cartoon_color, aquamarine, chain G
enable morph*

mset 1 x30
madd 1-30
madd 30 x30
madd 31-60
madd 60 x30
madd 60-31
madd 30 x30
madd 30-1

mplay

# set view matrix again since morph resets zoom
set_view (\
     0.802717209,    0.122951634,    0.583526075,\
    -0.466776222,   -0.479430526,    0.743127942,\
     0.371141285,   -0.868901372,   -0.327459961,\
    -0.002007872,    0.007674277, -472.066711426,\
   174.404602051,  180.046813965,  170.140151978,\
   444.443115234,  497.135711670,   20.000000000 )

# save movie in format 350,600