Y2R_active_complex

# Y2R_active_complex_surface.pml

# ------------------------------

reinitialize

# load structures
# ---------------
fetch 7yon

# create objects
# --------------
create Y2, chain R
create YY, chain L
create Galpha, chain A
create Gbeta, chain B
create Ggamma, chain G

# general definitions and graphics
# --------------------------------
set hash_max, 100
set bg_rgb, white
set depth_cue, on
set fog, 1.0
set fog_start, 0.6
set orthoscopic, on
clip slab, 100
set opaque_background, on
set ray_shadows, off
hide everything
#@D:\pymol_examples\def_colours.pml

# fold cartoon
# ------------
dss
set cartoon_fancy_helices, on
# set cartoon_highlight_color, white
set cartoon_transparency, 0.0
show cartoon, YY
color orange, YY
color gold, Y2
color firebrick, Galpha
color deepblue, Gbeta
color aquamarine, Ggamma
#set cartoon_color, paleblue, receptor

# molecular surface
# -----------------
set solvent_radius, 2.0 ;# larger probe radius -> smoother surface
#create msurface, receptor
#hide all, msurface
show surface, Y2 or G*
#set transparency, 0.5 , Y2
#set surface_color, white, msurface

# viewpoint
# ---------
orient Y2 ; # this orients the 7TM domain along its principal axis such that the helices are parallel to x (longest dimension)
turn z, 90 ; # rotate 7TM such that helices are vertical
turn y, -90 ; # rotate around vertical axis
zoom

# ***********PASTE VIEW MATRIX HERE ************
set_view (\
    -0.405147344,    0.369955540,   -0.836055279,\
     0.663268447,   -0.510442257,   -0.547287405,\
    -0.629229963,   -0.776261151,   -0.038575511,\
     0.000014737,    0.000027344, -380.651245117,\
   182.448532104, 180.916763306, 172.781600952,\
   339.229797363, 422.072998047,   20.000000000 )

# for final raytracing:
# util.performance(0)
# ray/draw 800, 1200
# png 4eiy_protein.png